Pushistik↯❤
Команда форума
- Регистрация
- 6 Июл 2017
- Сообщения
- 393
- Реакции
- 97
- Баллы
- 28
Введение в SourcePawn программирование
Это руководство призвано дать вам самые основные представления по написанию сприптов в SourcePawn. Pawn - это "скриптовый" язык используемый для внедрения функциональности в других программах. Это означает, что это не самостоятельный язык, как C++ или Java, и его элементы будут отличаться в различных приложениях. SourcePawn - это вариация языка Pawn, используемая в SourceMod.
Это руководство не расскажет вам, как писать SourceMod плагины; оно предназначено для получения общих представлений о синтаксисе и семантике этого языка.
Особенности языка
Pawn может показаться очень похожим на другие языки программирования, например C, но Pawn от них фундаментально отличается. Не столь важно, чтобы вы сейчас же поняли его отличия, но они понадобятся, если вы уже знаете один из языков программирования:
- Pawn не собирает мусор
Pawn, как язык, не имеет встроенных ресурсов памяти, и потому он не мусорит. Если функция выделит память, то вы отвечаете за её освобождение. - Pawn не объектно-ориентированный язык
Pawn является процедурным и полагается на подпрограммы. Также у него нету C подобных структур. - Pawn не функциональный
Pawn является процедурным и не поддерживает функции "лямбды" (Lambda), поздние присвоения и все то, что можно найти в языках высшего уровня, таких как Python и Ruby. - Pawn однопоточный
- Pawn не интерпретируемый
Ну, почти. Он интерпретируется на очень низком уровне. Вы должны скомпилировать код, из которого получится бинарный файл. Эта программа будет работать на той платформе, которую использует сервер. Это ускоряет загрузку и позволяет легче находить ошибки.
Этот язык был выпущен ITB CompuPhase. Язык разработан для устройств низкого уровня и таким образом конечные программы очень маленькие по размеру и очень быстрые.
Идентификаторы/ключевые слова
Идентификаторы представляет собой набор букв, цифр и/или нижнего подчеркивания, что представляет собой нечто уникальное. Идентификаторы вводятся с учетом регистра (в отличие от PHP, где иногда это не требуется). Идентификаторы не начинаются с какого-либо специального символа, но они должны начинаться с буквы.
Есть несколько зарезервированных символов, которые имеют особое значение. Например, if, for и return специальные конструкции в языке, которые будут описаны позднее. Они не могут быть использованы в качестве названий идентификаторов.
Переменные
Существует несколько важных конструкций, которые вы должны знать, прежде чем приступить к написанию сценария. Во-первых, это переменные. Переменная - это идентификатор, который содержит данные. Например, переменная "a" может содержать числа "2", "16", "0" и так далее. Переменные создаются для хранения данных внутри программы. Переменные должны быть объявлены до их использования, с помощью ключевого слова "new". Данные можно присвоить переменной, используя знак равенства (=). Пример:
PHP:
new a, b, c, d;
a = 5;
b = 16;
c = 0;
d = 500;
- Однострочные (могут содержать только произвольные числовые данные), как показано выше
- Многострочные (могут содержать целый ряд текстовых символов)
Однострочные могут содержать 32 бита цифровых данных. Многострочные - последовательный список из UTF-8 символов. Однострочные не имеет своего типа, однако они могут быть маркированы(tagged). Тег позволяет вам указывать, где определенную ячейку можно использовать. Типичные теги:
- (пусто), или _ - Нет тега. Обычно используют для целых чисел (Integers).
- Float - используют для чисел с плавающей точкой (небольших).
- bool - используют для хранения значений true (истина) или false (ложь).
Со строками все по другому, они будут рассмотрены далее.
Объявления
Примеры разных правильных объявлений переменных:
PHP:
new a = 5;
new Float:b = 5.0;
new bool:c = true;
new bool:d = 0; // работает, поскольку 0 равно false (ложь)
PHP:
new a = 5.0; // несоответствие тегов. 5.0 должо быть с тегом Float
new Float:b = 5; // несоответствие тегов. 5 должно быть без тега.
PHP:
new a; // значение 0
new Float:b; // значение 0.0
new bool:c; // значение false
Переменным могут быть присвоены данные после создания. Пример:
PHP:
new a, Float:b, bool:c;
a = 5;
b = 5.0;
c = true;
Примечания и любой текст, который пишется после "//" считается "комментарием", а не фактическим кодом. Есть два стиля комментариев:
- // - двойная косая черта, всё, следующее после этой строки, игнорируется
- /* */ - много-строчный комментарий, весь текст, внутри звездочек, игнорируются
Массивы
Вы можете группировать код в виде "массивов", разделенных { и }. Это фактически создает возможность работать с целым массивом как с одним оператором. Например:
PHP:
{
здесь;
какой-то;
код;
}
Массив объявляется с помощью квадратных скобок. Вот некоторые примеры массивов:
PHP:
new players[32]; // Набор из 32 однострочных (числовых) данных
new Float:origin[3]; // Набор из 3 чисел с плавающей точкой
PHP:
new numbers[5] = {1, 2, 3, 4, 5}; // В numbers будут храниться значения 1, 2, 3, 4 ,5
new Float:origin[3] = {1.0, 2.0, 3.0}; // В origin будут храниться значения 1.0, 2.0, 3.0
PHP:
new numbers[] = {1, 3, 5, 7, 9};
Использование массива равносильно использованию обычной переменной. Единственное отличие состоит в том, что он должен быть индексируемым. Индексирование массива означает присутствие возможности выбрать элемент, который вы хотите использовать.
Вот пример кода с использованием индексов:
PHP:
new numbers[5], Float:origin[3];
numbers[0] = 1;
numbers[1] = 2;
numbers[2] = 3;
numbers[3] = 4;
numbers[4] = 5;
origin[0] = 1.0;
origin[1] = 2.0;
origin[2] = 3.0;
Использование неверного индекса вызовет ошибку. Например:
PHP:
new numbers[5];
numbers[5] = 20;
Вы можете использовать любые выражения, как индекс. Например:
PHP:
new a, numbers[5];
a = 1; // сделает a = 1
numbers[a] = 4; // сделает numbers[1] = 4
numbers[numbers[a]] = 2; // сделает numbers[4] = 2
Строки являются удобным способом хранения текста. Символы хранятся в массиве. Строка ограничивается нулевым символом или 0. Без нулевого символа, Pawn не знает, где остановить чтение строки. Все строки в SourcePawn используют кодировку UTF-8.
Отметим, что строки имеют комбинацию из массивов и однострочных переменных. Это означает, что вы должны знать заранее, как много места будут использовать строки, поэтому строки не являются динамичными. Они могут лишь вырасти до размера, которым вы их ограничили.
Примечание для специалистов: они фактически не однострочные. SourcePawn использует 8-битные строки для хранения массивов в качестве оптимизации. Это и есть то, что делает строки типом, а не меткой.
Строки были созданы почти в равной степени и для массивов. Например:
PHP:
new String:message[] = "Hello!";
new String:clams[6] = "Clams";
PHP:
new String:message[7], String:clams[6];
message[0] = 'H';
message[1] = 'e';
message[2] = 'l';
message[3] = 'l';
message[4] = 'o';
message[5] = '!';
message[6] = 0;
clams[0] = 'C';
clams[1] = 'l';
clams[2] = 'a';
clams[3] = 'm';
clams[4] = 's';
clams[5] = 0;
Заметим, что строка должна быть заключена в двойных кавычках, а символ в одиночных.
Символы
Особенность текста может быть использована в любой строке или однострочной переменной. Например:
PHP:
new String:text[] = "Crab";
new clam;
clam = 'D'; // Устанавливает однострочной переменной значение 'D'
text[0] = 'A'; // Меняет 'C' на 'A', сейчас получилось 'Arab'
clam = text[0]; // Устанавливает однострочной переменной значение 'A'
text[1] = clam; // Меняет 'r' на 'A', сейчас получилось 'AAab'
PHP:
new clams[] = "Clams"; // Не верно, нужен тип String
new clams[] = {'C', 'l', 'a', 'm', 's', 0}; // Верно, но это НЕ СТРОКА.
Следующим важным понятием являются функции. Функции идентификаторов или имен, которые выполняют действия. Это означает, что когда вы их активируете, они выполняют конкретную последовательность кода. Есть несколько типов функций, но все функции активируется одинаковым образом. "Вызов функции" является термином ссылающимся на функцию действия. Функция числовых переменных строятся так:
Примеры:функция(<параметры>)
PHP:
show(56); // Активирует функцию "show" и присваивает ей число 56
show(); // Активирует функцию "show" без каких-либо данных, пустую
show(a); // Активирует функцию "show" и присваивает ей переменную с данными переменной a
Существуют два типа вызова функции:
- Прямой вызов - вы специально вызываете функцию в своем коде.
- Обратный вызов - применение вызова функции в вашем коде, как если бы это было событием триггера (совокупность условий, инициирующих выполнение действия).
Существуют пять видов функций:
- native - прямая, внутренняя функция, предусмотренная в приложении.
- public - функция обратного вызова, что делает её видимой для приложения и других сценариев.
- normal - нормальная функция, которую вы можете только вызвать.
- stock - нормальная функция, которая если не используется, то не компилируется.
- forward - функция представляет собой глобальное событие, если вы его вызвали, то она будет исполняться.
Весь код в Pawn должен существовать в функциях. Это основное отличие от языков, таких как PHP, Perl и Python, которые позволяют вам писать глобальный код. Это происходит потому, что Pawn вызывается на основе другого языка: он реагирует на действия от родительского приложения и функции должны быть написаны для обработки этих действий.
В отличие от переменных функции не нужно объявлять, прежде чем использовать их. Функции имеют две части: модель и тело. Модель содержит имя вашей функции и параметры, которые она будет принимать. Тело представляет собой простой блок кода.
Пример функции:
PHP:
AddTwoNumbers(first, second)
{
new sum = first + second;
return sum;
}
PHP:
AddTwoNumbers(first, second)
AddTwoNumbers - название функции.
first - название первого параметра, который представляет собой простой элемент.
second - название второго параметра, который представляет собой простой элемент.
В теле создается новая переменная sum и присваивается ей значение этих двух параметров, добавленных совместно (другие выражения будут позже). Важно заметить, что оператор return обозначает конец функции и возврат с полученными значениями из этой функции. Все функции возвращают значения после завершения. Это означает, например:
PHP:
new sum = AddTwoNumbers(4, 5);
Функция может принимать любые типы значений. Она может вернуть любую однострочную переменную, но не массивы или строки. Пример:
PHP:
Float:AddTwoFloats(Float:a, Float:b)
{
new Float:sum = a + b;
return sum;
}
Можно, конечно, передавать переменные в функции:
PHP:
new numbers[3] = {1, 2, 0};
numbers[2] = AddTwoNumbers(numbers[0], numbers[1]);
PHP:
new a = 5;
ChangeValue(a);
ChangeValue(b)
{
b = 5;
}
public
Публичные функции используются для осуществления обратных вызовов. Вы не должны создавать какую-либо публичную функцию, если это вынудит выполнение обратного вызова. Например, вот два обратных вызова из sourcemod.inc:
PHP:
forward OnPluginStart();
forward OnClientDisconnected(client);
PHP:
public OnPluginStart()
{
/* Здесь код */
}
public OnClientDisconnected(client)
{
/* Здесь код */
}
native
Native имеют встроенные функции, предоставляемые приложением. Вы можете вызвать их, как если бы они были normal функциями. Например, SourceMod имеет следующие функции:
PHP:
native FloatRound(Float:num);
PHP:
new num = FloatRound(5.2); // Результат в num = 5
Вы можете передавать массивы или строки в качестве параметров. Важно отметить, что они идут как ссылка, то есть копия данных не делается, а отдается непосредственно ссылка на данные. Существует простой способ объяснить это более конкретно.
PHP:
new example[] = {1, 2, 3, 4, 5};
ChangeArray(example, 2, 29);
ChangeArray(array[], index, value)
{
array[index] = value;
}
PHP:
example[2] = 29;
PHP:
CantChangeArray(const array[], index, value)
{
array[index] = value; // Не компилируется
}
Выражения
Выражения являются точно такими же, какими они существуют в математике. Это группы операторов/символов, которые приходятся на один фрагмент данных. Они часто заключены в скобках (внутри скобок). Они содержат строгий "порядок операций". Они могут содержать переменные, функции, цифры и выражения сами могут быть вложенные внутрь других выражений, и даже приняты в качестве параметров.
Приведем пример простейшего выражения:
PHP:
0; // Возвращает число 0
(0); // Также возвращает число 0
Порядок операций выражения аналогичен языку C. Вот несколько примеров выражений:
PHP:
5 + 6; // Вычисляет как 11
5 * 6 + 3; // Вычисляет как 33
5 * (6 + 3); // Вычисляет как 45
5.0 + 2.3; // Вычисляет как 7.3
(5 * 6) % 7; // Модульный оператор, вычисляет как 2
(5 + 3) / 2 * 4 - 9; // Вычисляет как 7
PHP:
new a = 5 * 6;
new b = a * 3; // Вычисляет как 90
new c = AddTwoNumbers(a, b) + (a * b);
Есть несколько полезных дополнительных операторов в Pawn. Например:
PHP:
new a = 5;
a = a + 5;
PHP:
new a = 5;
a += 5;
Кроме того, существуют операторы увеличение/понижения:*, /, -, +
|, &, ^, ~, <<, >>
PHP:
a = a + 1;
a = a - 1;
PHP:
a++;
a--;
До: переменная увеличивается до определения и остальная часть выражения видит новое значение.
Пост: переменная увеличивается после определения и остальная часть выражения видит старое значение.
Например:
PHP:
new a = 5;
new b = a++; // b = 5, a = 6
new c = ++a; // a = 7, c = 7
Существуют шесть операторов для сравнения двух числовых значений, а результат является либо истиной (не ноль), либо ложью (ноль):
- a == b - действительно, если a и b имеют одинаковые значения.
- a != b - действительно, если b имеет другое значение.
- a > b - действительно, если a больше b
- a >= b - действительно, если a больше или равно b
- a < b - действительно, если a меньше b
- a <= b - действительно, если a меньше или равно b
Например:
PHP:
(1 != 3); // Определяется как истина, поскольку 1 не равно 3
(3 + 3 == 6); // Определяется как истина, поскольку 3+3 равно 6
(5 - 2 >= 4); // Определяется как ложь, поскольку 3 меньше 4
Действительные операторы
Действительные операторы могут быть скомбинированы тремя булевыми (boolean) операторами:
- a && b - истина, если a и b истинные. Ложь, если a и (или) b ложные.
- a || b - истина, если a или b (или обе переменные) истинные. Ложь, если обе переменные a и b ложные.
- !a - Истина, если a ложь. Ложь, если a истина.
Например:
PHP:
(1 || 0); // Определяется как истина, так как выражение 1 истинное
(1 && 0); // Определяется как ложь, так как выражение 0 ложное
(!1 || 0); // Определяется как ложь, так как выражение !1 ложное
Два важных понятия левого и правого значений или левостороннее и правостороннее значения. Левостороннее значение имеет то, что появляется на левой стороне выражения, а правостороннее значение - на правой стороне выражения.
Например:
PHP:
new a = 5;
Правила:
- Выражения никогда не будут левосторонними значениями.
- Переменные являются двумя: левосторонними и правосторонними значениями.
Условия
Условия позволяют вам запускать код, если определенное условие выполнено.
Если соответствует (if/else if)
Если соответствует одно или более условий. Например:
PHP:
if (a == 5)
{
/* Код будет запущен, если условие будет истинным */
}
PHP:
if (a == 5)
{
/* Код */
}
else if (a == 6)
{
/* Код */
}
else if (a == 7)
{
/* Код */
}
PHP:
if (a == 5)
{
/* Код */
}
else
{
/* Код, который будет запущен если нет истинного выражения */
}
Оператор выбора будет ограничен условием. Он необходим для выражения, выполняющего код для целого ряда возможных значений. Например:
PHP:
switch (a)
{
case 5:
{
/* Код, который будет выполняться, если a равно 5 */
}
case 6:
{
/* Код, который будет выполняться, если a равно 6 */
}
case 7:
{
/* Код, который будет выполняться, если a равно 7 */
}
case 8, 9, 10:
{
/* Код, который будет выполняться, если a равно или 5, или 9, или 10 */
}
default:
{
/* Код, который будет выполняться, если ни одно условие не соответствует */
}
}
Циклы позволяют вам без труда повторять выполнение кода, пока условие истинно.
For циклы
For циклы - это циклы, которые состоят из четырех частей:
- Оператор инициализации - запускается один раз перед первым циклом.
- Оператор условия - проверяет условие и запускает следующий цикл, в том числе первый. Цикл прекращается, когда это выражение становится ложным.
- Оператор итерации - запускается после каждого цикла.
- Тело цикла - запускается каждый раз, пока оператор условия вычисляется как истинный.
PHP:
for ( /* инициализация */ ; /* условие */ ; /* итерация */ )
{
/* тело */
}
PHP:
new array[10] = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10};
new sum = SumArray(array, 10);
SumArray(const array[], count)
{
new total;
for (new i = 0; i < count; i++)
{
total += array[i];
}
return total;
}
new i = 0 - создает новую переменную для цикла i и устанавливает её в 0.
i < count - только запускает цикл, если i меньше, чем count. Это гарантирует, что чтение цикла прекращается в определенный момент. В этом случае, мы не хотим читать недействительные индексы в массиве.
i++ - увеличивает i на единицу после каждого цикла. Это гарантирует, что цикл не будет запущен вечно. В конце концов i станет слишком большим и цикл завершится.
Таким образом, функция SumArray будет циклом каждого действительного индекса массива, каждый раз добавляя это значение в sum.
While циклы
While циклы являются менее распространенными, чем for циклы, но на самом деле это более простые циклы. Они имеют только две части:
- Оператор условия - проверяется перед началом каждого цикла. Цикл прекращается, когда условие становится ложным.
- Тело цикла - запускается каждый раз пока цикл выполняется.
PHP:
while ( /* условие */ )
{
/* тело */
}
PHP:
/* инициализация */
while ( /* условие */ )
{
/* тело */
/* итерация */
}
PHP:
SumArray(const array[], count)
{
new total, i;
while (i < count)
{
total += array[i];
i++;
}
return total;
}
PHP:
do
{
/* тело */
}
while ( /* условие */ );
Существуют два случая, когда нам нужно контролировать цикл:
- пропустить одну итерацию или цикл и продолжить выполнение цикла, как обычно;
- разорвать цикл целиком, прежде чем он закончится.
Допустим у вас есть функция, которая принимает массив и ищет соответствия цифр. Вы хотите его остановить, когда число будет найдено:
PHP:
/**
* Возвращает массив, если индекс значения или -1, или не найден.
*/
SearchInArray(const array[], count, value)
{
new index = -1;
for (new i = 0; i < count; i++)
{
if (array[i] == value)
{
index = i;
break;
}
}
return index;
}
Кроме того, ключевое слово continue пропускает итерации цикла. Например, мы хотим суммировать все четные числа:
PHP:
SumEvenNumbers(const array[], count)
{
new sum;
for (new i = 0; i < count; i++)
{
if (array[i] % 2 == 1)
{
/* Пропускаем оставшуюся часть итерации цикла */
continue;
}
sum += array[i];
}
return sum;
}
Область действия относится к удобочитаемости кода. Это означает, что код одного уровня не может быть "виден" в коде другого уровня. Пример:
PHP:
new A, B, C;
Function1()
{
new B;
Function2();
}
Function2()
{
new C;
}
PHP:
Function1()
{
new B;
Function1();
}
Это свойство можно объяснить проще тем, что область действия переменной равна уровню её вложенности. То есть переменная на глобальной области действия видна для всех функций. Переменная в локальной области действия видна всему блоку кода расположенному "ниже" этого уровня. Например:
PHP:
Function1()
{
new A;
if (A)
{
A = 5;
}
}
PHP:
Function1()
{
new A;
if (A)
{
new B = 5;
}
B = 5;
}
Динамические массивы
Динамические массивы - это массивы, которые не имеют фиксированного размера. Например:
PHP:
Function1(size)
{
new array[size];
/* Код */
}
Динамические массивы действительны только в локальной области действия, так как код не может существовать на глобальном уровне.
Расширенное объявление переменных
Переменные могут быть объявлены другим путем, чем просто new.
decl
По умолчанию, все переменные в Pawn будут инициализированы, как нуль. Если есть явная инициализация, переменная инициализируется для выражения = определенным символам. В локальной области действия, это может потребовать время на выполнение. Ключевое слово decl (которое действительно только в локальной области действия) было введено, чтобы позволить решать пользователю: хочет ли он инициализировать переменную или нет.
Примечание: decl не должно быть использовано на одну однострочную переменную. Это будет не выгодно.
Например:
PHP:
new c = 5;
new d;
new String:blah[512];
Format(blah, sizeof(blah), "%d %d", c, d);
Заметим, что blah не должен быть нулевой. В период времени с объявления new и и перемещения в Format(), массив blah никогда не будет загружен или прочитан. Данный код будет более эффективен, если будет написанный следующим образом:
PHP:
new c = 5;
new d;
decl String:blah[512];
Format(blah, sizeof(blah), "%d %d", c, d);
PHP:
new c = 5;
new d;
decl String:blah[512];
PrintToServer("%s", blah);
Format(blah, sizeof(blah), "%d %d", c, d);
PHP:
new c = 5;
decl d;
decl String:blah[512];
Format(blah, sizeof(blah), "%d %d", c, d);
Заметим, что это легко и эффективно обезопасит строки. Пример ниже показывает, как предотвратить строки от мусора:
PHP:
decl String:blah[512];
blah[0] = '\0';
- Используйте decl только, если в период объявления и загрузки/чтения значения, вы абсолютно уверены, что есть по крайней мере одно хранилище/операция, которая отдает переменной действительные данные.
- Не оптимизируйте преждевременно. Кроме того, нет необходимости использовать decl на не массивы, поскольку нет никаких дополнительных затрат на инициализацию одного однострочного значения.
Этот пример не является столь эффективным, как decl:
PHP:
new String:blah[512] = "a";
Также обратите внимание, что он является неправильным для явной инициализации decl:
PHP:
decl String:blah[512] = "a";
static
Ключевое слово static входит в глобальную и локальную область действия. Оно имеет различные значения в каждой из них.
Глобальный static
Глобальные static переменные могут быть доступны только в рамках того же файла.
Например:
PHP:
// file1.inc
static Float:g_value1 = 0.15f;
// file2.inc
static Float:g_value2 = 0.15f;
Локальный static
Локальная static переменная является видимой лишь из её местной области действия.
Например:
PHP:
MyFunction(inc)
{
static counter = -1;
counter += inc;
return counter;
}
Возьмем следующий пример:
PHP:
MyFunction(5);
MyFunction(6);
MyFunction(10);
Преимуществом локальных static переменных является то, что вам не придется загромождать свой сценарий глобальными переменными. До тех пор, пока переменной не нужно читать другую функцию, Вы можете его пихать внутрь функции и её сохранение будет гарантировано.
Заметим, что static может существовать в любой локальной области действия:
PHP:
MyFunction(inc)
{
if (inc > 0)
{
static counter;
return (counter += inc);
}
return -1;
}
Всем спасибо за внимание!
Уроки SourcePawn (Содержание)
Последнее редактирование: